GNUPlot 4D

Input data:
 X   Y     Z      Velocity

1    3    700    2100
5    0    600    1200
8    1    500    1000
5    2    700    3000   
1    3    700    1200
4    3    800    4400
6    3    700    2000
9    5    500    1200
6    4    600    2000
2    6    700    3000
6    6    800    4000
9    6    600    3600
1    7    600    2200
4    7    800    2600
7    7    800    1200
1    9    500    1200
3    9    600    3600
6    9    700    1200
8    9    700    3700
1    9    500    2000

#!/bin/sh
gnuplot -persist << PLOT

set dgrid3d 100,100 gauss 1.5
dataFile='kontur.txt'

set table dataFile.'.grid'
splot dataFile u 1:2:3
unset table

set table dataFile.'.color'
splot dataFile u 1:2:4
unset table

set view 60,45
set hidden3d
set palette defined (0 "red", 0.25 "orange", 0.5 "yellow", 0.75 "green", 1 "blue")
set cblabel "velocity (m/s)"
set autoscale cbfix
set pm3d

unset dgrid3d
set ticslevel 0
set xlabel 'X-COORD (m)' rotate parallel
set ylabel 'Y-COORD (m)' rotate parallel
set zlabel 'Depth (m)' rotate parallel
set zrange [400:800] reverse
splot sprintf('< paste %s.grid %s.color', dataFile, dataFile) u 1:2:3:7 with pm3d notitle

quit
PLOT